Fun with Arduino 30 DCC Servo Decoder

Based on the DCC Accessory Decoder from the previous video we can create a DCC Servo Decoder. A servo decoder can be used to operate turnouts on the model railway layout, or to operate a gate, or garage doors … or to move the arm of a semaphore signal. Or, using a relay, we can switch the polarity of ‘electrofrog’ turnouts, along with operating the servo.

All we have to do is to add the code to operate the servo to the DCC accessory control that already works. That way a DCC address can now operate a servo and/or can switch an output.

In the code, what we need to add is to toggle between two servo setpoint angles based on the DCC status and the code to control the servo with a millis() timer. To find the correct servo angles the Servo Tuner code of video 26 can be used after which we edit these angles into this DCC decoder code.

Read on below the video …

At the top of the code we configure how many servos we have, and at what speed we want to operate them:

#define NUMSERVOS   6 // Enter the number of servos here
#define SERVOSPEED 30 // [ms] between servo updates, lower is faster

// GO TO setup() TO CONFIGURE DCC ADDRESSES, PIN NUMBERS, SERVO ANGLES

#include <DCC_Decoder.h>
#include <Servo.h> 

unsigned long timetomove;

typedef struct DCCAccessoryData {
  int   address;   // User Configurable DCC address
  byte  outputpin; // User Configurable Arduino pin
  byte  dccstate;  // Internal use DCC state of accessory: 1=on, 0=off
  byte  angle;     // Internal use current angle of servo
  byte  setpoint;  // Internal use current angle of servo
  byte  offangle;  // User Configurable servo angle for DCC state = 0
  byte  onangle;   // User Configurable servo angle for DCC state = 1
  Servo servo;
};
DCCAccessoryData servo[NUMSERVOS];

void BasicAccDecoderPacket_Handler(int address, boolean activate, byte data) {
  address -= 1;
  address *= 4;
  address += 1;
  address += (data & 0x06) >> 1;
  // address = address - 4 // uncomment this line for Roco Maus or Z21
  boolean enable = (data & 0x01) ? 1 : 0;
  for (int i=0; i<NUMSERVOS; i++) {
    if (address == servo[i].address) {
      if (enable) servo[i].dccstate = 1;
      else servo[i].dccstate = 0;
    }
  }
}

void setup() { 
// CONFIGURATION OF SERVOS
// Copy & Paste as many times as you have servos 
// The amount must be same as NUMSERVOS
// Don't forget to increment the array index
  servo[0].address   =   1 ; // DCC address
  servo[0].outputpin =  14 ; // Arduino accessory pin
  servo[0].servo.attach( 3); // Arduino servo pin
  servo[0].offangle  =  70 ; // Servo angle for DCC state = 0
  servo[0].onangle   = 150 ; // Servo angle for DCC state = 1

  servo[1].address   =   2 ; // This is an accessory without servo
  servo[1].outputpin =  15 ;
 
  servo[2].address   =   3 ;
  servo[2].outputpin =  16 ;

  servo[3].address   =   4 ;
  servo[3].outputpin =  17 ;

  servo[4].address   =   5 ;
  servo[4].outputpin =  18 ;

  servo[5].address   =   6 ;
  servo[5].outputpin =  19 ;

  DCC.SetBasicAccessoryDecoderPacketHandler(BasicAccDecoderPacket_Handler, true);
  DCC.SetupDecoder( 0x00, 0x00, 0 );

  for(byte i=0; i<NUMSERVOS; i++) {
    pinMode     (servo[i].outputpin, OUTPUT);
    digitalWrite(servo[i].outputpin, LOW);
    servo[i].angle = servo[i].offangle;
    servo[i].servo.write(servo[i].angle);
    delay(1000); // wait 1 second before activating the next servo
  }
}

void loop() {
	
  for(byte i=0; i<NUMSERVOS; i++) {
    DCC.loop(); // Call to library function that reads the DCC data
    if (servo[i].dccstate == 1) {
      digitalWrite(servo[i].outputpin, HIGH);
      servo[i].setpoint = servo[i].onangle;
    }
    else {
      digitalWrite(servo[i].outputpin, LOW);
      servo[i].setpoint = servo[i].offangle;
    }
  }

// Move the servos when it is timetomove
  if (millis() > timetomove) {
    timetomove = millis() + (unsigned long)SERVOSPEED;
    for (byte i=0; i<NUMSERVOS; i++) {
     if (servo[i].angle < servo[i].setpoint) servo[i].angle++;
      if (servo[i].angle > servo[i].setpoint) servo[i].angle--;
      servo[i].servo.write(servo[i].angle);
    }
  }
}

When we connect the optocoupler to the DCC voltage and upload this code to the Arduino, we can control servos and accessories. Testing … yes it works!

In the next video we are going to control a stepper motor.

— 0 —